Preparing for Wrath

Well with Wrath upon us. I have decided to compile a list of things i want to get done before the expansion. I dont know if it is possible with the limited play time that i have but here is my list.

Warlock Macros

From WoWikki

Useful macros for warlocks
From WoWWiki
Jump to: navigation, search
Macros
General guides

Macros Beginners Guide
Making a macro
UI FAQ/Macros and scripts
Category:Macros
Useful macros (by class)

Useful macros for druids Useful macros for hunters Useful macros for mages Useful macros for paladins Useful macros for priests Useful macros for rogues Useful macros for shamans Useful macros for warlocks Useful macros for warriors
Contents
[hide]

* 1 Crowd Control
o 1.1 Fear / Banish Focus Macro
o 1.2 Chain-Fear Focus Macro
* 2 Pet Macros
o 2.1 Pet management
o 2.2 Pet Attack Toggle
o 2.3 Pet Attack => Grind
o 2.4 Pet Attack => Grind => Drain Soul
o 2.5 Pet Attack => Cast DoT’s in Sequence => Hold Alt to nuke
o 2.6 Pet Attack => Find and destroy shaman’s totems
o 2.7 Voidwalker Sacrifice / Succubus Seduction / Felhunter Devour
o 2.8 All pet abilities in one button / AI
o 2.9 Imp Dark Pact / No Imp Life Tap
o 2.10 Devour Magic off Target else Yourself
o 2.11 Fel Domination + Summon Pet
o 2.12 4 Demons on 1 button
o 2.13 Focus a Target out of combat, then attack in combat
o 2.14 Voidwalker management on one button
o 2.15 Voidwalker Health Recovery
o 2.16 Two-button Total Pet Control
o 2.17 Summon All Pets
o 2.18 Focused Seduction
o 2.19 Devour Magic – 3v3 Arena Style
o 2.20 Advanced Spell Lock with Focus
o 2.21 Advanced Devour Magic
* 3 Stone Management
o 3.1 Wand/Spellstone use on 1 button
o 3.2 Two Macros to Switch between Wands and Firestone
o 3.3 Soulstone Macro
o 3.4 2 healthstones on one button
o 3.5 Healthstone and Healing Potion
o 3.6 Healthstone use/summon, Ritual of Souls in group
* 4 General Macros
o 4.1 Fire or Shadow casting
o 4.2 Affliction DoT castsequence
o 4.3 Immolate & Incinerate in one button
o 4.4 PvP Prep
o 4.5 Grind Macro
o 4.6 Grind, amplified, no error noise or message
o 4.7 Amplify Curse with Curse
o 4.8 Amplified Trinket’d Curse of Doom
o 4.9 Multidrain
o 4.10 Mount flying or dreadsteed

[edit] Crowd Control
[edit] Fear / Banish Focus Macro

This is a rather complex macro, utilizing focus to keep track on the target. Casting fear or banish will hit your target as well as create a focus of which all consecutive fears and banishes will target. Having a dead focus will be treated as if you had no focus.

* No modifier casts Howl of Terror
* Alt fears the target
* Ctrl banishes the target
* Ctrl+Shift banishes down-ranked
* Shift clears your focus

/cast [nomod]Howl of Terror
/stopmacro [nomod]
/focus [mod:shift,nomod:ctrl]none;[target=focus,harm,nodead]focus;[harm,nodead];none
/cast [target=focus,mod:alt]Fear;[target=focus,mod:ctrl,mod:shift]Banish(Rank 1);[target=focus,mod:ctrl]Banish

[edit] Chain-Fear Focus Macro

* If you do not have a focus it will set focus on your mouseover target.
* It will cast fear on your focus.
* If you do not have a focus, it will cast fear on your target.
* Will null your focus if you click the macro button with the control key held down, or if your target is dead.

#showtooltip
/focus [target=focus, noexists][target=focus, dead] mouseover
/cast [nomodifier, target=focus] Fear
/stopmacro [nomodifier]
/clearfocus [modifier:ctrl]

Note that if you select the macro picture the first line of the macro will make this icon the fear spell, and will allow your usual tooltip to display

[edit] Pet Macros
[edit] Pet management

Both your warlock and pet can engage the same target at the same time, given a long-casting opener and a modifier key.

/petattack [modifier]
/cast Shadow Bolt

[edit] Pet Attack Toggle

Pet attack toggle button.

/petattack [target=pettarget,noexists]
/petfollow [target=pettarget,exists]

[edit] Pet Attack => Grind

This one also makes sure your pet is attacking the target; useful to take some of the finger-work out of grinding. You’ll want to fine-tune the sequence depending on your level, spec, and the mobs you’re fighting.

/petattack
/castsequence reset=combat/target Corruption, Curse of Agony, Life Tap, Drain Life, Shoot

This one has two behaviors depending on whether you are in combat or not.

* Not in combat, it will send the pet and start a Shadow Bolt of your highest rank. If you hold ctrl down out of combat, it will instead start with a Curse of Recklessness WITHOUT sending the pet. This is a typical “pull to me” use where it is assumed your pet can/will taunt the mob off you asap. Usually, your pet will engage the mob before your Shadow Bolt actually strikes the mob. Wait carefully before proceeding to the in combat chain (below).
* In combat, it will start casting with Curse of Agony WITHOUT changing the pet’s current target. This is useful in cases where you have already caught aggro as well as cases where you change your target to another mob (e.g., you got an “add.”) NB: If you pulled with Recklessness (or any other curse), it will change to Agony.

The castsequence you can view below; you may wish to change the spells used or add/insert spells into the chain. As is typical with macros like this, you press it once to begin the actions, then wait for appropriate cooldowns before pressing it again. Recommended: The ? icon for this macro.

/cast [nomodifier:ctrl,nocombat] Shadow Bolt; [nocombat]Curse of Recklessness
/petattack [nomodifier:ctrl,nocombat]
/castsequence [combat] reset=target Curse of Agony, Immolate, Corruption

[edit] Pet Attack => Grind => Drain Soul

If you want to cram even more functionality into that grinding button, here’s the above macro, plus the feature that if you hold Alt while pressing it, it will cast Drain Soul instead.

/petattack [nomodifier]
/castsequence [nomodifier] reset=target/combat Corruption, Curse of Agony, Immolate, Shadow Bolt, Shadow Bolt, Shoot
/cast [modifier:alt] Drain Soul

[edit] Pet Attack => Cast DoT’s in Sequence => Hold Alt to nuke

Sends your pet to attack, and casts immolate. Press again for Curse of Agony, and again for Corruption. Then hold alt, and nuke away. If you’re not grouped, and have a voidwalker out, you will alternate between Shadow Bolt and Searing Pain when holding alt. I suggest you keep Immolate first as it gives you time to cast without interrupts, and lets your demon cast or attack in time to build up aggro.

/petattack
/castsequence [modifier:alt,nogroup,pet:Voidwalker/pet:Felhunter] Searing Pain, Shadow Bolt, Shadow Bolt
/cast [modifier:alt] Shadow Bolt
/castsequence reset=combat/target Immolate, Curse of Agony, Corruption

[edit] Pet Attack => Find and destroy shaman’s totems

This macro sends your pet to find and destroy shaman’s totems. The first totem is Fire Resistance Totem increasing the fire resistance of party members within 20 yards by XX. Where XX depend on rank of Fire Resistance Totem.) specially for firelocks for decrease fire resistances. Second totem – Windfury Totem enchants all party members main-hand weapons with wind, if they are within 20 yards. Each hit has a 20% chance of granting the attacker 1 extra attack with XXX extra attack power. Where XXX depend on rank of Windfury Totem.) – it prevent from lot of huge damages. Third totem – Earthbind Totem slowing the movement speed of enemies (it must be destroyed, specially for running locks). The fourth totem in macro – Tremor Totem blocks all fear attempts, it is very important to remove this as often as possible, this totem does not have a cooldown as such the Shaman will be able to recast as often as possible. The last totem is Grounding Totem and will block your next spell cast.

The Macro sends each command in sequence and the most recent successfull command will be taken. This means that your Macro should be backwards in priority (e.g. the last totem is the most important, with the first line being the least important).

/petattack
/petattack [target=Fire Resistance Totem]
/petattack [target=Windfury Totem]
/petattack [target=Earthbind Totem]
/petattack [target=Tremor Totem]
/petattack [target=Grounding Totem]

[edit] Voidwalker Sacrifice / Succubus Seduction / Felhunter Devour

This macro will do the following. If you have your Voidwalker summoned and are out of combat it will cast Consume Shadows, or Sacrifice if you are in combat. If you have your Succubus summoned it will cast Seduction on your focus or if you have no focus then it will cast Seduction on your current target. If you have your Felhunter summoned it will cast Devour Magic on your focus.

#showtooltip
/cast [pet:voidwalker,nocombat] Consume Shadows; [pet:voidwalker,combat] Sacrifice
/cast [pet:Succubus,target=focus] Seduction; [pet:Succubus] Seduction
/cast [pet:Felhunter,target=focus] Devour Magic
/focus [target=focus,dead]

Note If you assign the button to it it will change the graphic to match whatever spell your current pet will use and will show the correct tooltip on mouseover.
[edit] All pet abilities in one button / AI

221 characters long to get the most out of all pet abilities, this macro will:
1. If you have a Succubus out, cast Seduction on your focus.
2. If you have an Imp out, cast Dark Pact.
3. if you have a Felhunter out, cast Spell Lock on your focus.
4. If in combat with a voidwalker, cast Dark Pact and then Sacrifice.
5. If out of combat with a voidwalker, cast Consume Shadows and Health Funnel.

#showtooltip
/cast [pet:Imp]Dark Pact;[pet:Succubus,target=focus]Seduction;[pet:Felhunter,target=focus]Spell Lock
/stopmacro [nopet:voidwalker]
/cast [combat]Dark Pact;Sacrifice
/cast [nocombat]Consume Shadows;Health Funnel

This is another version of the above macro which has been modified to include all of the most important pet abilities.

#showtooltip
/cast [pet:voidwalker,combat] Sacrifice
/cast [pet:Succubus,target=target] Seduction
/cast [pet:Felhunter,target=target] Spell Lock
/cast [pet:Felguard,target=target] Intercept

[edit] Imp Dark Pact / No Imp Life Tap

Dark Pact if you have an Imp out, Life Tap if you don’t have an Imp out. Depending on your playstyle, this may let you get by with only 1 keybinding for both Dark Pact and Life Tap.

/cast [pet:imp] Dark Pact; Life Tap

Another variant for this macro would be to use Dark Pact if your Imp or Felhunter is out since both have a nice mana pool, otherwise use Life Tap. If you use this macro with ? as icon it will show the icon for the available spell.

#showtooltip [pet:imp/felhunter] Dark Pact; Life Tap
/cast [pet:imp/felhunter] Dark Pact; Life Tap

[edit] Devour Magic off Target else Yourself

Devour Magic on your target, Devours off of you when right clicked.

/cast [button:2,target=player] Devour Magic; Devour Magic

[edit] Fel Domination + Summon Pet

If you are demonologist and have Fel Domination it will cast it and summon the pet you want. Just change “pet you want to summon” with the name of your desired minion, for example /cast Summon Voidwalker (Summon).

/cast Fel Domination
/stopcasting
/cast Summon [pet you want to summon](Summon)

In addition, if you want the ability to summon more than one pet using Fel Domination with only one button, this macro works wonders. Edit for your minion preference. If Fel Domination is not up, it will summon the minion normally. NOTE: if you use the ? mark icon for the macro, you will only see the icon for Fel Domination, although the tooltip will display the correct Summon.

#showtooltip [mod:ctrl] Summon Felhunter; [mod:alt] Summon Voidwalker; [mod:shift] Summon Imp; Summon Felguard
/cast Fel Domination
/cast [mod:ctrl] Summon Felhunter; [mod:alt] Summon Voidwalker; [mod:shift] Summon Imp; Summon Felguard

[edit] 4 Demons on 1 button

One button, 4 Demons. Left = Felhunter, Right = Voidwalker, Shift click = Imp, Control click = Succubus. Saves bar space.

/cast [modifier:shift]Summon Imp(Summon); [modifier:ctrl]Summon Succubus(Summon); [button:2]Summon Voidwalker(Summon); Summon Felhunter(Summon)

[edit] Focus a Target out of combat, then attack in combat

This macro will set a focus on your target outside of combat and when in combat will command your pet to either assist the focussed target if it is friendly or attack the focussed target if it is hostile. Can be modified to clear focus when used or can be made so that focus is kept so pet can be juggled between 2 targets in combat. Also, if out of combat can send your pet to attack once a focus is set. There’s really a lot of ways someone can tweak with this so figure out what works for you and change to your liking.

/focus [nocombat]
/petattack [target=focus, exists,harm,combat]; [target=focustarget,exists,harm,combat]; target

[edit] Voidwalker management on one button

1. If you do not have a Voidwalker out it will summon it.
2. If you have a Voidwalker and ARE NOT in combat, will cast Consume Shadows and heal Voidwalker.
3. If you have a Voidwalker and ARE in combat, will Sacrifice Voidwalker.

/cast [nopet:Voidwalker] Summon Voidwalker
/cast [pet:Voidwalker,nocombat] Consume Shadows
/cast [pet:Voidwalker,combat] Sacrifice

A variant Voidwalker Summon/Sacrifice macro: If in combat and pet is Voidwalker, cast Sacrifice, otherwise Summon Voidwalker.

/cast [target=pet,dead] Summon Voidwalker; [combat,pet:Voidwalker] Sacrifice; Summon Voidwalker

Note: The “[target=pet,dead]” part is necessary to keep from getting a “Your pet is dead” error when resummoning shortly after casting Sacrifice.
[edit] Voidwalker Health Recovery

Often when soloing with an affliction build, a warlock ends combat with near full health and mana. This quickly gets your voidwalker back up to fighting condition in a single click. If you aren’t using your voidwalker or are in combat it acts just like the normal health funnel button.

#showtooltip
/cast Health Funnel
/cast [nocombat, pet:Voidwalker] Consume Shadows

[edit] Two-button Total Pet Control

With two buttons (macros) you can have total pet control if you make them context sensitive. The point of this is that a keyboard can become utterly cluttered, and requiring more than 2 buttons for 5-6 functions on your pets results in more buttons than preferred being in an unreachable place. Before the macro I’d bind pet function 1 (attack) and 5 to two buttons, but occasionally the situation comes up where the pet needs to be recalled, or needs to be told to stay in a position in sentry mode. Using the mouse + pet bar for these more advanced techniques wastes valuable time, multiple buttons waste valuable pet space. I therefore wrote a macro to bring it all down to two buttons, based on having a target selected or not.

Macro 1:

/petfollow
/petpassive
/petattack [harm]

Macro 2:

/petfollow [pet:succubus]
/cast [harm] Spell Lock
/cast [help] Devour Magic
/cast Seduction
/cast Sacrifice
/cast Intercept
/petstay [noexists]
/petdefensive [noexists]

This allows you to do the following things:

* Send your pet to attack pressing button 1 while targeting an enemy
* Get your pet to return to you immediately by deselecting any targets and pressing the same button again
* Have your pet use its special attack (Seduce, Sacrifice, Intercept, Spell Lock) when you target an enemy with the second button
* Have your pet (other than the Voidwalker) stay in one place and become aggressive when pressing the second button and no target is selected
* Have them return again to you and become passive again pressing the first button again
* You can now re-seduce without the succubus being blocked by an ongoing seduce
* The Felhunter will attempt to devour Magic on targeted friendlies, and spell lock targeted enemies.

Basically everything you ever need to do with your pet in 2 buttons.
[edit] Summon All Pets

This one is a very simple macro that allows you to summon any pet you wish to summon. Just left click to summon an Imp. Hold alt and left click to summon a Succubus. Hold ctrl and left click to summon a felhunter. Hold shift and left click to summon a Voidwalker. Right click to summon a Felguard. Hold shift and right click to summon a Felsteed. Hold alt and right click to summon a Dreadsteed. That covers every possible summon, includes the mounts. Even if you don’t have some of the summons it doesn’t matter because it’ll just mean that you can’t use that one until you get the spell. So lets say you don’t have a Felhunter and you ctrl right click, nothing will happen. Yet all the other summons will work fine. So no matter what level you are it will work with whatever pets you have.

#showtooltip
/cast [btn:2] Summon Felguard
/cast [btn:2,mod:shift] Summon Felsteed
/cast [btn:2,mod:alt]  Eye of Kilrogg
/cast [mod:alt] Summon Succubus
/cast [mod:ctrl] Summon Felhunter
/cast [mod:shift] Summon Voidwalker
/cast Summon Imp

Same thing, more space efficient.

#showtooltip
/cast [btn:2] Summon Felguard; [btn:2,mod:shift] Summon Felsteed; [btn:2,mod:alt] Eye of Kilrogg; [mod:alt] Summon Succubus; [mod:ctrl] Summon Felhunter; [mod:shift] Summon Voidwalker; Summon Imp

Or if you don’t or can’t use multiple mouse buttons, this will also work. Notice the lack of the Eye of Kilrogg, Felsteed/Dreadsteed, and Imp summons. Also be aware that if you use keyboard shortcuts (for example you press “3″ for the third action button) you MUST remap your shift key to use this or any other macro that has a shift modifier. Shift+# keys switch your action bars by default.

#showtooltip
/cast [mod:alt] Summon Felguard; [mod:ctrl] Summon Voidwalker; [mod:shift] Summon Succubus; Summon Felhunter

[edit] Focused Seduction

* Upon use, the macro will Focus your target, and have your succubus Seduce it.
* When used for the second time, and your Focused target, i.e. the Seduction target, is alive, it will re-seduce it, regardless of what your current target is. It will not focus your current target, and seduce that; it will re-seduce it’s focused target.
* If used during Seduction, it will break the seduction and re-seduce the focused target.
* If clicked while “Alt” is being pressed, it will cancel the previous focus and assign a new focus on your current target.

#show Seduction
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/petstay
/petfollow
/stopcasting
/cast [pet:succubus,target=focus,exists,harm] Seduction; Seduction

[edit] Devour Magic – 3v3 Arena Style

* On use, this macro will cast Devour Magic on the target specified without breaking your current target.
* Useful for 3v3 Arenas, requires a middle mouse button.

#showtooltip
/cast [pet:Felhunter,button:1,target=party1] Devour Magic;
/cast [pet:Felhunter,button:2,target=party2] Devour Magic;
/cast [pet:Felhunter,button:3,target=player] Devour Magic;

Again, same thing more space saving, and using modifiers rather than mouse buttons (for those keyboard enthusiasts out there). Normal click will cast it on you, alt+click (or alt+hotkey) will cast it on party member 1, ctrl+click (or hotkey) will cast it on party 2. Since only the Felhunter has Devour Magic, there’s no need to ensure that the Felhunter is out. I recommend replacing your normal Devour Magic button on your pet toolbar with one of these.

#showtooltip
/cast [mod:alt,target=party1] Devour Magic; [mod:ctrl,target=party2] Devour Magic; [target=player] Devour Magic

[edit] Advanced Spell Lock with Focus

* When used, this macro will focus your current target (if you don’t already have a focus) and cast Spell Lock on that target. If shift is held down while using this macro it will focus your current target and cast Spell Lock on that target (changing focus), if you don’t have a target it will simply clear your focus. If ctrl is held down while using this macro it will simply Spell Lock the target your mouse is hovering (this way you won’t lose your current target).

#showtooltip Spell Lock
/clearfocus [modifier:shift]
/focus [target=focus, noexists]
/cast [nomodifer, pet:Felhunter, target=focus, harm] Spell Lock; [modifier:ctrl, pet:Felhunter, target=mouseover, harm] Spell Lock

[edit] Advanced Devour Magic

* When used, this macro will cast Devour Magic on you. If shift is held down while using this macro it will cast Devour Magic on your current target.

#showtooltip Devour Magic
/cast [modifier:shift, pet:Felhunter] Devour Magic; [pet:Felhunter, target=player] Devour Magic

[edit] Stone Management
[edit] Wand/Spellstone use on 1 button

This macro manages equipping, conjuring and using spellstones and wands to one button. Clicking it without any modifier will use the currently equipped item, and alt-clicking it will swap between the items. If a spellstone isn’t present it will create one, and if the slot is empty it will equip the wand. Change the name of the wand to the one you use.

/cast [nomod,equipped:wand] Shoot;[nomod,equipped:relic] Master Spellstone;[mod, equipped:wand]Create Spellstone
/equip [mod, equipped:wand]Master Spellstone;[mod]Wand of the Netherwing

This will allow you to turn your wand’s auto-shoot on or use your equipped Spellstone with one button.

/cast [equipped:Wand] Shoot; Master Spellstone

Alternative method with Shadow Ward as an alt-click.

#show Shadow Ward
/cast [nomodifier,equipped:wand] Shoot
/cast [nomodifier,equipped:relic] Major Spellstone
/cast [modifier:alt] Shadow Ward

[edit] Two Macros to Switch between Wands and Firestone

These two macros will allow you to attack with your Firestone in hand (or go back to combat equipment after fishing) and swap it out to use your wand.

#showtooltip
/equip <Name of you main hand weapon>
/equip <Name of your off hand item>
/equip Firestone
/startattack

This second one will equip your wand with the first press, and shoot your wand with the second one.

#showtooltip
/equip <Name of your wand>
/cast Shoot

[edit] Soulstone Macro

This macro will on right click make a soulstone (change for appropriate level), left click, use it and on alt left click cast it on yourself.

#showtooltip Minor Soulstone
/cast [modifier:alt,target=player] Minor Soulstone; [button:1] Minor Soulstone;  [button:2] Create Soulstone

[edit] 2 healthstones on one button

One button, 2 Healthstones. Click to create a rank 6 (Master) Healthstone or use it if one exists. Click with any modifier to to the same to a rank 5 (Major) healthstone.

/cast [nomod]Master Healthstone;Major Healthstone
/cast [nomod]Create Healthstone;Create Healthstone (Rank 5);

[edit] Healthstone and Healing Potion

Note: It is currently impossible to write a macro that will have you use a healthstone if you have one and a potion if you do not.

* Left-click uses a Healthstone; right-click a potion named in the macro
* If you choose an icon for the macro rather than allowing the program to choose one for you, the macro button in your action bar will be grayed if you do not have a healthstone.
* In all cases, only the cooldown for your healthstone will be shown.

#showtooltip
/use [button:1] Healthstone; [button:2] Superior Healing Potion

This macro summons a Healthstone if you are not in combat, uses a Healthstone AND potion if you are. Note, depending on whether you have a Healthstone and/or potion in inventory at the time (and applicable cooldowns), you may see error messages. The macro also cannot tell whether you have a Healthstone in inventory or not. These are unavoidable – the macro will still do the best it can. NB: You must edit this to indicate the correct Healthstone and healing potion names.

/cast [nocombat]Create Lesser Healthstone
/use [combat]Lesser Healthstone
/use [combat]Lesser Healing Potio

[edit] Healthstone use/summon, Ritual of Souls in group

This will allow to use a healthstone with one click, summon with another, however in groups you will cast Ritual of Souls rather than a single summon.

#showTooltip Master Healthstone
/cast [group, button:2] Ritual of souls
/cast [button:2] Create Healthstone
/use [button:1] Master Healthstone

When you first log in it’ll show you a red question mark icon until you make your first stone. You can change the first line to “#showTooltip Create Master Healthstone” to fix this, however it will display the number of soulshards remaining instead of healthstone.

[edit] General Macros
[edit] Fire or Shadow casting

Sometimes you’ll want to ONLY cast fire or shadow spells at a target, most notably fire elementals who are immune to fire. Here’s a couple of macros to do so. To start out, hold down alt while clicking the button to cast the appropriate curse on the target (or cast a different curse, such as CoA beforehand). After that, click away till dead. The fire macro seems to work better for Demonology specced locks. Feel free to substitute your own talent spells or rearrange the order.

#showtooltip
/castsequence [mod:alt] Curse of the Elements; reset=10/target/combat Immolate, Incinerate, Searing Pain, Incinerate

#showtooltip
/castsequence [mod:alt] Curse of Shadow; [mod:ctrl] Shadow Bolt; reset=10/target/combat Corruption, Shadow Bolt, Shadowburn, Shadow Bolt, Seed of Corruption, Shoot (if your wand is shadow damage)

[edit] Affliction DoT castsequence

When used, this macro will first cast Immolate, Corruption,Curse of Agony and finally Siphon Life on your target. If the button is left unpressed for 10 seconds or you change your target it will reset the sequence and the next spell that will be cast will be Immolate.

/castsequence reset=10 Immolate, Corruption, Curse of Agony, Drain Life

This macro will utilize and maximize your DPS(Damage Per Second) and wont conflict with the DoTs(Damage Over Time) duration on your situated target.

Edit notes: Changed Siphon Life to Drain Life Siphon Life did not work as that is not the correct spell name Drain life is correct and works
[edit] Immolate & Incinerate in one button

On regular click this will cast Immolate, hold down alt to cast Incinerate.

#showtooltip
/cast [modifier:alt] Incinerate; Immolate

Make sure that you select the “question mark” for the icon for the button so the proper icon will show up (Immolate as it’s default). When you hit “Alt” the button will change to show the Incinerate icon.
[edit] PvP Prep

This macro will summon your Voidwalker if he’s not already out. Feel free to substitute different pets/armors if your situation differs!

/cast [nopet] Fel Domination /castsequence [nopet] Summon Voidwalker(Summon);[pet] Demonic Sacrifice /cast [pet] Demon Armor

And another one, especially useful after a pet has been killed, sacrificed, or dismissed. Summons your steed after your buffs, so you can get back to the action.

#showtooltip
/castsequence [nopet,mod:alt] Summon Voidwalker; [nopet,mod:ctrl] Summon Felhunter; [nopet] Summon Felguard; [pet] reset=4 Soul Link, Demon Armor, Summon Dreadsteed

Another useful PvP macro: This one buffs you with Fel Armor, Soul Link, Detect Invisibility, and Unending Breath. The reason you have the last two buffs is that it makes it harder for hunter, priests, etc. to dispel your Fel Armor.

#showtooltip
/target <Self>
/castsequence Fel Armor, Soul Link, Detect Invisibility, Unending Breath

A simple way to do the macro above without making it specific to your player name:

#showtooltip
/castsequence [target=player] Fel Armor, Soul Link, Detect Invisibility, Unending Breath

[edit] Grind Macro

This is intended for grinding. The assumption is that you have the following spells: Curse of Agony, Corruption, Drain Life, Health Funnel and Drain Soul. You should have some level of these spells by level 12. After that point, the macro will just use the most advanced version of each spell (except Drain Soul). The Voidwalker or Felguard are good pets when using this macro.

To use, simply press the button when each spell is finished. To drain the soul (and create a soul shard)hold down the <Alt> key while pressing the button.

/petattack
/cast [nocombat] Curse of Agony
/castsequence [nomodifier,combat] reset=target/combat Corruption,Life Tap,Drain Life,Health Funnel,Shoot
/cast [modifier:alt] Drain Soul(Rank 1)

Here is the same macro with Amplify Curse (in case you have it)

/petattack
/cast [nocombat] Amplify Curse
/cast [nocombat] Curse of Agony
/castsequence [nomodifier,combat] reset=target/combat Corruption,Life Tap,Drain Life,Health Funnel,Shoot
/cast [modifier:alt] Drain Soul(Rank 1)

And another one (without pet attack):

#showtooltip
/castsequence [mod:ctrl] Searing Pain; [mod:alt] Incinerate; reset=10/combat/target Immolate, Corruption, Incinerate, Life Tap, Drain Life, Searing Pain

And another one (with pet attack):

/petattack
/castsequence [mod:ctrl] Searing Pain; [mod:alt] Incinerate; reset=10/combat/target Immolate, Corruption, Incinerate, Life Tap, Drain Life, Searing Pain

[edit] Grind, amplified, no error noise or message

/petattack [nocombat]
/console Sound_EnableSFX 0
/use item:31615
/console Sound_EnableSFX 1
/script UIErrorsFrame:Clear();
/castsequence reset=5/target Unstable Affliction,Immolate,Curse of Agony,Corruption,Siphon Life

The above macro sends your pet against the target, then turns off the error sound and uses the Ancient Arcane Draenei Relic to get plus spell power (but uses its item number to stay under the 255 character limit). Then it clears the red error message and turns the error sound back on (so if a spell gets blocked you hear it and see the message) and starts the grind cast sequence Unstable Affliction, Immolate, Curse of Agony, Corruption, and Siphon Life. The sequence resets if you get a new target or if 5 seconds pass. Note that Drain Life and Drain Soul are not included. I find that I prefer having them on a separate keys since I often use them out of sequence.

[edit] Amplify Curse with Curse

Will do a one click Amplify Curse (if its up) with the curse of your choice. If Amplify Curse is not up, it will just cast the curse as normal.

#showtooltip Curse of Agony
#show Curse of Agony
/cast Amplify Curse
/stopcasting
/cast Curse of Agony

#showtooltip Curse of Exhaustion
#show Curse of Exhaustion
/cast Amplify Curse
/stopcasting
/cast Curse of Exhaustion

Added: #showtooltip Curse of Agony —> shows curse of agony’s tool tip on macro mouseover

#show Curse of Agony —> use ? icon and it will show CoA icon and cooldown (as in removes Amplify curse cooldown from button)

Adding the following lines will eliminate unwanted error messages.

#showtooltip Curse of Agony
#show Curse of Agony
/script local function x() end local y = UIErrorsFrame.AddMessage UIErrorsFrame.AddMessage = x
/cast Amplify Curse
/script UIErrorsFrame.AddMessage = y
/stopcasting
/cast Curse of Agony

Yet another one, this one is more space efficient (patch 2.3 made /stopcasting pretty much obsolete, unless you need a panic button), this will show the tooltip of the curse you will cast AFTER Amplify Curse (if you have the ? mark icon selected, it will ONLY show the Amplify Curse icon). If you click the macro normally, it will cast Amplify then Curse of Agony; with the alt key, Amplify then CoD; ctrl is Amplify and Curse of Exhaustion. Like above, if Amplify is not up, it will cast the curse normally (although you may get an error message).

#showtooltip [mod:alt] Curse of Doom; [mod:ctrl] Curse of Exhaustion; Curse of Agony
/cast Amplify Curse
/cast [mod:alt] Curse of Doom; [mod:ctrl] Curse of Exhaustion; Curse of Agony

[edit] Amplified Trinket’d Curse of Doom

This macro will use your available Trinket, cast Amplify Curse, and Curse of Doom all in one button.

#showtooltip Curse of Doom
#show Curse of Doom
/use 13
/stopcasting
/use 14
/stopcasting
/cast Amplify Curse
/stopcasting
/cast Curse of Doom

Be wary this will still cast Curse of Doom regardless if you have a trinket or Amplify Curse available.

Note: As of 2.3 this macro may require a second click to cast Curse of Doom.

[edit] Multidrain

All three drains on a single button (via ctrl and alt).

/stopmacro [noharm]
/cast [nomodifier,nochanneling:Drain Soul(Rank 1)] Drain Soul(Rank 1)
/cast [modifier:ctrl,nochanneling:Drain Mana] Drain Mana
/cast [modifier:alt,nochanneling:Drain Life] Drain Life

Same macro, more space efficient.

#showtooltip
/cast [mod:ctrl] Drain Mana; [mod:alt] Drain Life; Drain Soul

If you do NOT want to be able to start your drain over before it is completely channeled, use this instead:

#showtooltip
/cast [mod:ctrl,nochanneling:Drain Mana] Drain Mana; [mod:alt,nochanneling:Drain Life] Drain Life; [nochanneling:Drain Soul] Drain Soul

[edit] Mount flying or dreadsteed

If you are in a zone where you can use your flying mount this macro will use that. If not it will summon your dreadsteed.

/stopmacro [flying]
/cast [outdoors,nomounted,nomodifier:ctrl,flyable] Ebon Gryphon; [outdoors,nomounted] Summon Dreadsteed(Summon)
/dismount [mounted]

As an alternative a more advanced macro can be used. This differs from the above form in that it shows the appropriate tooltip based on what mount you are able to currently use. It also allows the use of the ALT key to summon the Dreadsteed within areas that allow flying. This macro also prevents you from accidentally dismounting while in the air. The outdoor check was omitted to save space.

#showtooltip [mod:alt] Summon Dreadsteed; [flyable] Tawny Windrider; Summon Dreadsteed
/cast [nomounted, mod:alt] Summon Dreadsteed; [nomounted,flyable] Tawny Windrider; [nomounted] Summon Dreadsteed
/dismount [mounted,noflying]

Same concept as the above macro, but will allow you to summon your Dreadsteed by pressing ctrl even in a flyable area, if you so desire. Also enables you to summon a minion of your choice (in this example a Felguard). Replace with your windrider and minion of choice.

#showtooltip [mod:ctrl] Summon Dreadsteed; [mod:alt] Summon Felguard; [flyable] Blue Windrider; Summon Dreadsteed
/cast [mod:ctrl] Summon Dreadsteed; [mod:alt] Summon Felguard; [flyable] Blue Windrider; Summon Dreadsteed
/dismount [noflying, mounted]